Versione aggiornata e corretta dello script Robocopy segnalato anni fa.

Differenze sostanziali:

• utilizza una piccola utility esterna (DateX) per recuperare il nome del giorno della settimana (da mettere in \windows o altro percorso presente nella PATH). In questo modo ho una sola operazione da pianificare e non sette passando come parametro il nome della cartella in cui salvare;
• non ne ho ancora capito il motivo ma Robocopy si impunta se la sorgente è la root di un disco (es. D:). La soluzione è spostarsi nella root del disco stesso prima di lanciare il comando. Ovviamente se dovete salvare una cartella non è necessario farlo (si possono rimuovere le righe 27-29).;
• la rimozione degli attributi system e hidden serve per le versioni di Robocopy incluse in Windows 7 e Server 2008 (forse anche Vista).

:: Estrae il giorno in formato AAAAMMGG per il nome del file di log
@For /F "tokens=1,2,3 delims=/ " %%A in ('Date /t') do @(
Set Giorno=%%A
Set Mese=%%B
Set Anno=%%C
Set Data=%%C%%B%%A
)

:: Estrae il nome del giorno della settimana sfruttando un'utility
:: Fonte: http://www.westmesatech.com/sst.html
for /f %%d in ('datex -f ddd') do set GiornoSettimana=%%d

Set Sorgente=d:
Set Destinazione=x:\robocopy\%GiornoSettimana%
Set FileLog=x:\registro\Backup%Data%.log

:: /MIR mirror, elimina i file in destinazione
:: /XD esclude una cartella
:: /XJ esclude junction points
:: /R:2 /W:5 attende 10 secondi e riprova 2 volte se la copia fallisce (default 30 secondi, 1 milione)
:: /V verbose output
:: /NP disattiva percentuale di progresso
:: /FFT FAT File Time (2-second granularity)
:: /LOG specifica la posizione del log (default schermo)

Set Opzioni=/MIR /XJ /R:2 /W:5 /V /NP /FFT /LOG:%FileLog%

:: Facendo la copia di una root (es. D:), mi sposto prima di lanciare robocopy
cd %Sorgente%\
%Sorgente%
Robocopy "%Sorgente%" "%Destinazione%" %Opzioni%

attrib -s -h "%Destinazione%"